2.30. Wat is het aantal uitgestroomde contractuele FTE personeel in loondienst (PIL) met een zorgverlenerfunctie?

Concepten

• Arbeidsovereenkomst
• Contractomvang
• Contractomvangwaarde
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• heeft deel
• heeft meeteenheid
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• FTE (36 uur per week)

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.30
2# Parameters: ?jaar
3# Ontologie: versie 3.0
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT ?Periode
12       ("Totaal Organisatie" AS ?Indeling)
13	   (ROUND(SUM(?fte_uitstroom) * 100) / 100 AS ?Som_uitgestroomde_contractuele_FTE36)
14{
15  SELECT ?Periode ?persoon
16			(IF(SUM(?fte * ?geldig_start) > SUM(?fte * ?geldig_eind),
17             SUM(?fte * ?geldig_start) - SUM(?fte * ?geldig_eind), 0) AS ?fte_uitstroom)
18  {
19    {
20      SELECT ?Periode ?persoon ?overeenkomst_afspraak ?geldig_start ?geldig_eind
21      {
22        #BIND(2024 AS ?jaar)
23        VALUES ?kw { 1 2 3 4 0 }
24
25        BIND(xsd:date(CONCAT(STR(?jaar), "-",
26             IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01","01-01"))))
27        )) AS ?p_start)
28
29        BIND(xsd:date(CONCAT(STR(?jaar), "-",
30             IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
31        )) AS ?p_eind)
32
33        BIND(IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode)
34
35        ?overeenkomst a onz-pers:ArbeidsOvereenkomst ;
36                      onz-pers:heeftOpdrachtnemer ?persoon ;
37                      onz-g:hasPart ?overeenkomst_afspraak .
38        ?overeenkomst_afspraak a onz-pers:WerkOvereenkomstAfspraak ;
39                                onz-g:isAbout ?functie ;
40                                onz-g:startDatum ?start_afspraak .
41        OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
42
43        BIND(IF(?start_afspraak <= ?p_start &&
44                ((?eind_afspraak >= ?p_start) || (!BOUND(?eind_afspraak))), 1, 0) AS ?geldig_start)
45        BIND(IF(?start_afspraak <= ?p_eind &&
46                ((?eind_afspraak >= ?p_eind) || (!BOUND(?eind_afspraak))), 1, 0) AS ?geldig_eind)
47
48        FILTER(?geldig_start = 1 || ?geldig_eind = 1)
49
50        # Selecteer alleen zorgverlenerfuncties
51        ?functie a onz-pers:ZorgverlenerFunctie .
52
53      }
54      GROUP BY ?Periode ?persoon ?overeenkomst_afspraak ?geldig_start ?geldig_eind
55    }
56
57    ?overeenkomst_afspraak onz-g:hasPart ?omvang .
58    ?omvang a onz-pers:ContractOmvang ; onz-g:isAbout ?omvang_waarde .
59    ?omvang_waarde a onz-pers:ContractOmvangWaarde ;
60                   onz-g:hasDataValue ?omvang_waarde_getal ;
61                   onz-g:hasUnitOfMeasure ?omvang_waarde_eenheid .
62    ?omvang_waarde_eenheid onz-g:hasDataValue ?eenheid_factor .
63
64    BIND(IF(?omvang_waarde_eenheid = onz-pers:fte_36,
65            ?omvang_waarde_getal,
66            ?omvang_waarde_getal / 36 * ?eenheid_factor) AS ?fte)
67  }
68  GROUP BY ?Periode ?persoon
69}
70GROUP BY ?Periode